Using Limilabs’ Ftp.dll with zOS Mainframes
Wednesday, December 17th, 2014I purchased the Limilabs FTP product for FTP because I needed to send data to and from an IBM mainframe from my VB.NET program running in Windows. In particular I needed to be able to submit jobs, and receive the job output. These notes show how it’s done.
Introduction
FTP to/from IBM computers is pretty much like any other FTP except for two things.
1. IBM Mainframe and Midrange computers mostly use EBCDIC encoding rather than ASCII. With the FTP defaults your data can be garbled and useless when it arrives at the other end.
2. The SITE command is used to submit jobs to the mainframe, and get the results back.
Getting Started
I created a class called “JazzFTP” to wrap the Limilabs’ code. This was going to contain the functions that I wanted for my project, and so I started by defining the common elements that all methods would use. In my situation every FTP would be authenticated, and would be exchanging text data (not binary) with the remote computer.
Here is the initial class definition:
Imports Limilabs.FTP.Client
Public Class JazzFTP
' This class wraps the FTP library from Limilabs (/ftp)
' All methods
' 1 Connect and logon using information from MySettings: Sub LoginFTP
' 2 Perform their action based on their parameters
' 3 Close the connection
Dim ftp As New Ftp()
Dim response As FtpResponse
Private Sub LoginFTP()
ftp.Connect(My.Settings.SubmitIP)
ftp.Login(My.Settings.Userid, My.Settings.Password)
End Sub
' My functions will be written here
End Class
Basic FTP
Here is my first method, a basic function to upload a text file: –
Function Upload(DestinationFile As String, Uploadfile As String) As String
LoginFTP()
ftp.TransfersDataType = FtpDataType.Ascii
response = ftp.Upload(DestinationFile, Uploadfile)
ftp.Close()
Return response.message
End Function
FTP’s default is Binary, which is correct if you are transmitting a .JPG or other binary object, and it probably doesn’t matter if you are transmitting text to/from another Windows computer or a Unix computer. However if you are transmitting to/from an IBM mainframe or midrange computer it probably needs EBCDIC rather than ASCII characters. You must tell it that the file is Ascii text, not binary, otherwise it won’t be converted and it will be gibberish when you examine it on the mainframe.
Although this code above works, it is very fragile: the FTP server has to be up and running, you have to get the connection details exactly right, the source and destination files must exist, and so on. Since I couldn’t guarantee all of these details, I enclosed the code in Try/Catch to deal with any errors. For the time being I’ve simply used MsgBox to display the error message.
Function Upload(DestinationFile As String, Uploadfile As String) As String
Try
LoginFTP()
ftp.TransfersDataType = FtpDataType.Ascii
response = ftp.Upload(DestinationFile, Uploadfile)
ftp.Close()
Return response.EndLine
Catch ex As Exception
MsgBox(ex.Message)
Return ex.Message
End Try
End Function
Download, which is not illustrated, is similar except that you’d use ftp.Download. Again, you specify:
ftp.TransfersDataType = FtpDataType.Ascii
Submitting Jobs and Receiving Job Output
Submitting a job is essentially an upload with a twist. Instead of uploading the file containing the job to a named file on the mainframe, you upload it to the JES (Job Entry System) input queue. Here is the basic code:
response = ftp.Site("FILETYPE=JES")
ftp.TransfersDataType = FtpDataType.Ascii
response = ftp.Upload("JES", JCLFile)
The first line uses “ftp.Site”. Site means that this is a site-specific command, something that the FTP system at the other end will presumably know about. For an IBM mainframe “FILETYPE=JES” means that the data is going to and from JES.
The third line uploads the file in which we have prepared our job: in this case JCLFile is a file containing something like this: –
//IBMUSERH JOB ,CLASS=A,MSGCLASS=H,NOTIFY=&SYSUID,COND=(8,LT) //*** COPY SOURCE INTO SOURCE LIBRARY //COPY EXEC PGM=IEBGENER //SYSPRINT DD SYSOUT=* //SYSIN DD DUMMY //SYSUT2 DD DSN=IBMUSER.MANAJAZZ.SRCLIB(CRDTA1),DISP=SHR //SYSUT1 DD *
Like any upload the FTP client syntax requires a destination file name, but because of the preceding FILETYPE=JES this will be ignored. I have written “JES” purely for documentation.
This will submit the job and it will run, appearing in the output like this:
Of course we can view the job output on the mainframe, but we may want to return it to Windows. We do this by downloading the file by naming the JobID – JOB00594 in this case – and again using the Site command. The essential code is: –
response = ftp.Site("FILETYPE=JES")
ftp.TransfersDataType = FtpDataType.Ascii
ftp.Download(Jobname, LocalPath)
But how do we get the Jobname? JES returns a message with this information when the job is submitted. We need to add code to the Job Submission logic to extract this from the message. In function JobSub
response = ftp.Upload("JES", JCLFile)
upload the job and (if all goes well) returns a message like
“It is known to JES as JOB00594″
This code extracts JOB00594” and puts it into variable JobName
Dim TestString As String = "It is known to JES as"
If Mid(response.Message, 1, Len(TestString)) = TestString Then 'Should be true
Jobname = Trim(Mid(response.Message, Len(TestString) + 1))
End If
Now, since it is logical that if we submit a job we’ll want to get it back, I coded this in the JobSub function: –
Function JobSub(JCLFile As String, ByRef Jobname As String) As FtpResponse
' JCLFile is path to a .JCL file (format .txt) containing the job to be submitted
' If successful submission, the job name is returned in JobName
Dim Tstring As String = ""
Try
Jobname = "Unknown"
LoginFTP()
response = ftp.Site("FILETYPE=JES")
ftp.TransfersDataType = FtpDataType.Ascii
response = ftp.Upload("JES", JCLFile)
Dim TestString As String = "It is known to JES as"
If Mid(response.Message, 1, Len(TestString)) = TestString Then 'Should be true
Jobname = Trim(Mid(response.Message, Len(TestString) + 1))
End If
JobGet(Jobname, False)
ftp.Close()
Catch ex As Exception
MsgBox(ex.Message, MsgBoxStyle.OkOnly, "Jazz FTP")
Return response
End Try
Return response
End Function
and I coded JobGet to accept these parameters: –
Function JobGet(Jobname As String, Optional Login As Boolean = True) As FtpResponse
' Get job output, save as Jobname.txt in Jazz Program Library.
If Login Then
LoginFTP()
End If
response = ftp.Site("FILETYPE=JES")
ftp.TransfersDataType = FtpDataType.Ascii
Dim LocalPath As String = My.Settings.UserCommonPath & "\" & My.Settings.Programs & "\" & Jobname & ".txt"
Jazzworkbench.ShowBtnResults(Jobname, Jazzworkbench.ResultsStatus.Pending)
ftp.Download(Jobname, LocalPath)
ftp.DeleteFile(Jobname)
Jazzworkbench.ShowBtnResults(Jobname, Jazzworkbench.ResultsStatus.JobReturned)
ftp.Close()
Return response
End Function
Once the job output has been downloaded I didn’t want to leave it cluttering up my Held Job Output Queue, so after the Download
ftp.DeleteFile(Jobname)
gets rid of it.
This all works for my test jobs (which are very quick) and provided that mainframe FTP server is available.
If you want to know any more about my project to revolutionize mainframe programming, then have a look at www.jazzsoftware.co.nz
Best wishes with your programming,
Robert Barnes.